Как задать вопрос по реквизиту

На форме выведен реквизит.

Нужно при выборе определенного значения выводить пользователю вопрос. «Вы точно уверены. При изменение удалю данные».

Если он согласен — значение реквизита меняется и я выполняю ряд других действий. А если нет — то ничего не делаю.

Событие ОбработкаВыбора я думаю мне нужна. Там видно что я выбрал и видно что я изменяю.

В нем я могу отказаться от изменения написав СтандартнаяОбработка = Ложь.

Но мне там надо задать вопрос. И тогда я выйду из контекста этой процедуры.

Видел пример с событием ПриЗакрытие, где задавалась глобальная переменная и в событие проверялось ее значение, а в обработке события вопроса завалось ее значение и писалось Закрыть() чем вызывало событие ПриЗакрытие еще раз.

Я вроде видел где то в типовых кон-ях подобно, но не помню где чтобы поискать

ПоказатьВопрос(Новый ОписаниеОповещения(«ОбработкаВыбораЗавершение», ЭтотОбъект),

                                                        «Закрывать форму?», РежимДиалогаВопрос.ДаНет)

И все. в эту процедуру он уже не вернется

Вижу такое решение.

В обработке ПриИзменение запросом получать значение реквизита из базы и сравнивать, в случае нужного ответа возвращать значение назад.

Но что то мне кажется это не правильно.

А не лучше ли сделать на манер стандартной блокировки редактирования номера документа?

То есть хочешь влезть в опасный реквизит — будь добр нажать кнопку, снимающую с него ридонли.

И регулировать все это дело доступностью полей, безо всяких голимых асинхронных вызовов

В общем зачем мне все это надо.

Есть реквизит «Вид операции»

Если вид операции №1 то обязательные реквизиты для заполнения одни.

Если другой — другие.

Если они зайдут и выберут первый вид операции, заполнят все. А потом захотят изменить тип, я хочу удалить значения реквизитов которые не участвуют в другом виде операции.

Но считаю что пользователь должен быть предупрежден

(5) не очень понял.

1.в событие ОбработкаВыбора сразу написать СтандартнаяОбработка = Ложь

2. Передать выбранное значение в вопросе

3. В обработке результата вопроса написать Объект.МойРевизит = ДопПараметры.ВыбранноеЗначение

Правильно?

(18) И откуда я возьму  эти значение других реквизитов, если их вводит пользователь?

Т.е. для одного вида операции важно чтобы был к примеру указан договор.

А для другого не важен, так зачем записывать его значение если пользователь умудрился его заполнить?

(20) Ну я готов услышать годную версию как это делается.

Есть документ. Им принимается продукция от поставщика, а так же он используется для приемки товара с другого склада внутри производства.

Если от поставщика то нужно знать номер и дату входящего документа.

Если же пользователь выберет вид операции «из другого склада», то у этой операции нет даты и номера входящего документа.

Я делаю эти реквизиты на форме не доступными

Но их же нужно очистить. А для этого я хочу спросить пользователя, что он знает что делает.

Предложу такое решение.

В палитре свойств элемента формы есть такие свойства:

«ОтображатьПредупреждениеПриРедактированиии» и «ПредупреждениеПриРедактировании» (см. http://joxi.ru/YmEYJjGhZ4Xebm )

Можно установить эти свойства, а при изменении поля уже безусловно выполнять нужный алгоритм.

В общем сделал так:

&НаКлиенте

Процедура ВидПриемкиОбработкаВыбора(Элемент, ВыбранноеЗначение, СтандартнаяОбработка)

    
    Если ВыбранноеЗначение <> Объект.ВидПриемки И ВыбранноеЗначение = ПолучитьВидПриемкиШокер() Тогда

        ПоказатьВопрос(Новый ОписаниеОповещения(«ПередЗакрытиемЗавершение», ЭтотОбъект,ВыбранноеЗначение),

        «Данные о входящем документе будут очищены. Продолжить?», РежимДиалогаВопрос.ДаНет);

        СтандартнаяОбработка = ЛОЖЬ;

    ИначеЕсли ВыбранноеЗначение <> Объект.ВидПриемки Тогда

        Элементы.ВходящийНомерДата.Доступность = Истина;    

        
    КонецЕсли;

КонецПроцедуры

&НаКлиенте

Процедура ПередЗакрытиемЗавершение(РезультатВопроса, ПараметрыЗаписи) Экспорт

        
         Если РезультатВопроса = КодВозвратаДиалога.Да Тогда

             Объект.ВидПриемки = ПараметрыЗаписи;

             Элементы.ВходящийНомерДата.Доступность = ЛОЖЬ;

             Объект.НомерВходящегоДокумента = Неопределено;

             Объект.ДатаВходящегоДокумента = Неопределено;

             Объект.ДатаПроизводства = Неопределено;

         КонецЕсли;

        
КонецПроцедуры

Функция ПолучитьВидПриемкиШокер()

    Возврат Перечисления.КА_ВидыПриемки.ИзШокера;

КонецФункции

Mort

26 — 26.04.18 — 11:14

В этой небольшой статье мы рассмотрим три способа, как в 1С показать пользователю вопрос.

В 1С Предприятие есть возможность средствами встроенного языка показать пользователю окно с вопросом и несколькими вариантами ответа, например “Вы уверены, что хотите уничтожить все документы с начала времен?” и ответы “Да, Нет, Я подумаю, Отмена”.

Метод «Вопрос»

Простейший способ показать вопрос пользователю – метод глобального контекста Вопрос. Этот метод является синхронным и к тому же модальным, и не рекомендуется к использованию, однако все еще встречается как в различных обработках и отчетах, так и в конфигурациях. Использовать его очень просто – мы указываем строку вопроса, варианты ответа, и обрабатываем выбранный пользователем вариант.

&НаКлиенте
Процедура КомандаВопрос(Команда)
	Ответ = Вопрос("Вы видите текст вопроса?", РежимДиалогаВопрос.ДаНет);
	Сообщить("Ваш ответ "+ Ответ);
КонецПроцедуры

Но, как всегда, есть нюансы. У этого метода есть несколько необязательных параметров, такие как таймаут, кнопка по умолчанию, заголовок, и кнопка таймаута (на ней будут отображаться оставшиеся секунды до таймаута). Кроме того, помимо системных режимов диалога (“Да/Нет”, “Ок/Отмена” и других), разработчик может задать свой список значений с вариантами ответа на вопрос.

&НаКлиенте
Процедура ВопросИзСписка(Команда)	
	СписокКнопок = Новый СписокЗначений;
	СписокКнопок.Добавить("Синий", "Синий");
	СписокКнопок.Добавить("Зеленый", "Зеленый");
	СписокКнопок.Добавить("Красный", "Красный");
	Ответ = Вопрос("Какой провод перерезать?", СписокКнопок, 20,,,"Красный");
	Сообщить("Вы перерезали "+ Ответ + " провод");
КонецПроцедуры

Ну и вишенка на торте. Мало кто знает, а еще меньше тех кто пользуется – вопрос можно задавать в виде форматированной строки. Попробуйте, вдруг вам понравится:)

&НаКлиенте
Процедура ВопросСРаскраской(Команда)	
	СписокКнопок = Новый СписокЗначений;
	СписокКнопок.Добавить("Синий", "Синий");
	СписокКнопок.Добавить("Зеленый", "Зеленый");
	СписокКнопок.Добавить("Красный", "Красный");
	
	ФорматированнаяСтрока = Новый ФорматированнаяСтрока("Какой провод перерезать? Варианты: ",
	Новый ФорматированнаяСтрока("Синий; ", , WebЦвета.Синий),
	Новый ФорматированнаяСтрока("Зеленый; ", , WebЦвета.Зеленый),
	Новый ФорматированнаяСтрока("Красный.", , WebЦвета.Красный));
	
	Ответ = Вопрос(ФорматированнаяСтрока, СписокКнопок, 20,,,"Красный");
	Сообщить("Вы перерезали "+ Ответ + " провод");	
КонецПроцедуры

Метод ПоказатьВопрос

Так как 1С планомерно отходит от модальности и синхронных методов, которые блокируют интерфейс и/или работу программы, рассмотрим асинхронный метод ПоказатьВопрос. Помимо всех параметров, рассмотренных выше, данный метод имеет еще один параметр: ОписаниеОповещенияОЗавершении. В этот параметр передается специальный объект с типом ОписаниеОповещения. Чтобы не мучиться и не писать в ручную, можно воспользоваться меню рефакторинга и преобразовать вызов.

Кликаем правой кнопкой на методе Вопрос в коде, в контекстном меню выбираем Рефакторинг / Нерекомендуемые синхронные вызовы / Преобразовать вызов. И платформа сама разделит наш метод на ПоказатьВопрос и обработку оповещения.

&НаКлиенте
Процедура КомандаВопрос(Команда)
	Ответ = Неопределено;
	ПоказатьВопрос(Новый ОписаниеОповещения("КомандаВопросЗавершение", ЭтотОбъект), "Вы видите текст вопроса?", РежимДиалогаВопрос.ДаНет);
КонецПроцедуры

&НаКлиенте
Процедура КомандаВопросЗавершение(РезультатВопроса, ДополнительныеПараметры) Экспорт	
	Ответ = РезультатВопроса;
	Сообщить("Ваш ответ "+ Ответ);	
КонецПроцедуры

Разумеется, получившийся код можно и нужно “причесать” – можно вынести описание оповещения в отдельную переменную, добавить дополнительные параметры, убрать ставший лишним код и т.д.

Метод ВопросАсинх

Начиная с версии 8.3.18 в платформе 1С появились новые асинхронные методы, работа с которыми во многом похожа на  asinc / await в JavaScript. Мы объявляем метод с ключевым словом Асинх, и в этом методе становится возможным использовать асинхронные методы. Перед вызовом метода ВопросАсинх мы указываем еще одно ключевое слово “Ждать”. Сам по себе метод ВопросАсинх не останавливает выполнение кода, и если не указать “Ждать”, то весь код ниже будет выполнен, и результат может быть не тот, что ожидался. По большому счету, это синтаксический сахар, призванный упростить код и облегчить жизнь разработчику.
Попробуйте убрать ключевое слово “Ждать” и сравните поведение программы 😉

&НаКлиенте
Асинх Процедура КомандаВопросАсинх(Команда)
	Ответ = Ждать ВопросАсинх("Вы заметили, что это асинхронный вопрос?", РежимДиалогаВопрос.ДаНет,,,"А ведь это асинхронный вопрос!");
	Сообщить("Ваш ответ "+ Ответ);
КонецПроцедуры

В остальном, этот метод имеет все те же параметры, что и метод “Вопрос”, который мы рассмотрели в самом начале.

Ответы

В зависимости от того, как мы задали параметр “Кнопки”, ответы могут быть самые различные. Если использовать РежимДиалогаВопрос, то у ответа тип значения будет КодВозвратаДиалога. Если же указать кнопки в виде списка значений, то в поле Ответ будет содержаться значение, привязанное к соответствующей кнопке. Типы значений в списке кнопок можно задавать самые различные. А следовательно, и логику обработки ответа можно реализовать самую разную, в зависимости от полученного значения и его типа.

&НаКлиенте
Процедура ОтветыРазныхТипов(Команда)
	СписокКнопок = Новый СписокЗначений;
	СписокКнопок.Добавить(2, "2");
	СписокКнопок.Добавить("Привет", "Привет");
	//В конфигурации должен быть справочник Организации с предопределенным элементом ОсновнаяОрганизация
	СписокКнопок.Добавить(ПредопределенноеЗначение("Справочник.Организации.ОсновнаяОрганизация"), "Справочник");
	СписокКнопок.Добавить(ТекущаяДата(), "Сегодня");
	СписокКнопок.Добавить(КодВозвратаДиалога.Пропустить, "Пропустить");
	Ответ = Вопрос("какой тип значения у выбранного ответа?", СписокКнопок);
	
	Если ТипЗнч(Ответ) = Тип("Число") Тогда
		Ответ = Ответ*2;
	ИначеЕсли ТипЗнч(Ответ) = Тип("Строка") Тогда
		Ответ = Ответ + " программист 1С!";
	ИначеЕсли ТипЗнч(Ответ) = Тип("СправочникСсылка.Организации") Тогда
		ОткрытьЗначение(Ответ);
	ИначеЕсли ТипЗнч(Ответ) = Тип("Дата") Тогда
		Ответ = НачалоДня(Ответ);			
	Иначе
		//Код ответа Пропустить, ничего не делаем
	КонецЕсли;	
	
	Сообщить("Тип значения " + ТипЗнч(Ответ) + "; значение " + Ответ);

КонецПроцедуры

Пользуйтесь асинхронными методами, задавайте пользователям коварные вопросы, и до новых встреч!

• Latest

• Votes
• Unanswered

Встала задача — перед записью документа произвести некоторые проверки и задать вопрос пользователю, в зависимости от ответа — провести документ или нет.

Все бы хорошо, но логика не модальных диалогов приводит нас к тому, что вопрос еще не отвечен, а процедура, вызвавшая ее, уже завершила свою работу.

Есть несколько вариантов решения, один — это замена стандартных команд своими, второй использование дополнительных переменных и повторный вызов процедуры.

В моем случае инициирует все процедура ПередЗаписью() (я делал в расширении, перед):

//Объявляем ряд глобальных переменных в контексте клиента
//Пока переменные не переопределены их значение равно - Неопределено
&НаКлиенте
Перем ОтказатьВПроведении;
&НаКлиенте
Перем глПараметрыЗаписи;



&НаКлиенте
Процедура Расш1_ПередЗаписьюПеред(Отказ, ПараметрыЗаписи)
    Если ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.Проведение Тогда
        глПараметрыЗаписи=ПараметрыЗаписи;
        Если ОтказатьВПроведении=Неопределено Тогда 
            ДиалогСВопросом();
            Отказ=Истина; // завершаем работу процедуры в самом ее зачатке
        Иначе 
            Отказ=ОтказатьВПроведении;
            ОтказатьВПроведении=Неопределено;
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ДиалогСВопросом()
    Оповещение = Новый ОписаниеОповещения("ПослеЗакрытияВопроса",ЭтотОбъект); 
    ПоказатьВопрос(Оповещение,Строка("Вы уверены что хотите провести отгрузку?"),
                    РежимДиалогаВопрос.ДаНет,0,КодВозвратаДиалога.Да,"Отгрузить товар?");    
КонецПроцедуры
 
&НаКлиенте
Процедура ПослеЗакрытияВопроса(Результат, Параметры) Экспорт
    Если Результат = КодВозвратаДиалога.Да Тогда
        ОтказатьВПроведении=Ложь;
    Иначе
        ОтказатьВПроведении=Истина;
    КонецЕсли; 
    Записать(глПараметрыЗаписи);
КонецПроцедуры

Вся мысль заключается в следующем:
После нажатия кнопки провести проверяется переменная ОтказатьВПроведении, если она равна неопределено, тогда вопрос еще не задавался запускаем выполнение процедур вопроса и ставим отказ в истину, чтобы документ не провелся. В процедуре после вопроса формируются новые значения переменной ОтказатьВПроведении (на этот момент ПередЗаписью уже завершился), и в конце снова запускаем запись с параметрами проведения. Переменная ОтказатьВПроведении уже имеет значение отличное от Неопределено, значит вопрос задавался, выполняем дальше процедуры/функции сообразуясь с ответом пользователя. Незабываем очистить переменную ОтказатьВПроведении.

UP 21/05/2022

Был много удивлен, увидев свой пост на этот вопрос заданный мной в гугле, но даже при этом я не удовлетворился описанным методом и упростил его использовав ПараметрыЗаписи:

ПередЗаписью (BeforeWrite)

Синтаксис:

ПередЗаписью(<Отказ>, <ПараметрыЗаписи>)

Параметры:

<Отказ>

Тип: Булево. 
Признак отказа от записи. Если в теле процедуры-обработчика установить данному параметру значение Истина, запись выполнена не будет и будет вызвано исключение.
Значение по умолчанию: Ложь.

<ПараметрыЗаписи>

Тип: Структура. 
Структура, содержащая параметры записи. Для формы документа существует два предопределенных параметра — РежимЗаписи и РежимПроведения. Они добавляются автоматически при вызове команд «Провести», «Провести и закрыть», «Отмена проведения».
Параметр РежимПроведения может отсутствовать, если режим проведения в документе не определен.

//НЕ Объявляем ряд глобальных переменных в контексте клиента

&НаКлиенте
Процедура Расш1_ПередЗаписьюПеред(Отказ, ПараметрыЗаписи)
    Если ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.Проведение Тогда
        Если ПараметрыЗаписи.Свойство("ОтказатьВПроведении") Тогда
            ДиалогСВопросом();
            Отказ=Истина; // завершаем работу процедуры в самом ее зачатке
        Иначе 
            Отказ=ПараметрыЗаписи.ОтказатьВПроведении;
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ДиалогСВопросом()
    Оповещение = Новый ОписаниеОповещения("ПослеЗакрытияВопроса",ЭтотОбъект); 
    ПоказатьВопрос(Оповещение,Строка("Вы уверены что хотите провести отгрузку?"),
                    РежимДиалогаВопрос.ДаНет,0,КодВозвратаДиалога.Да,"Отгрузить товар?");    
КонецПроцедуры
 
&НаКлиенте
Процедура ПослеЗакрытияВопроса(Результат, Параметры) Экспорт
    ПараметрыЗаписи=Новый Структура;
    ПараметрыЗаписи.Вставить("ОтказатьВПроведении",Результат = НЕ КодВозвратаДиалога.Да);
    Записать(ПараметрыЗаписи);
КонецПроцедуры